日期

Dates 模块提供了两种类型来处理日期：Date 和 DateTime，分别精确到日和毫秒；两者都是抽象类型 TimeType 的子类型。区分类型的动机很简单：不必处理更高精度所带来的复杂性时，一些操作在代码和思维推理上都更加简单。例如，由于 Date 类型仅精确到日（即没有时、分或秒），因此避免了时区、夏令时和闰秒等不必要的通常考虑。

Date 和 DateTime 类型都是基本不可变类型 Int64 的包装类。这两种类型的单个 instant 字段实际上属于 UTInstant{P} 类型。这种类型表示的是一种基于世界时间（UT）持续增长的机器时间 [1]。DateTime 类型并不考虑时区（用 Python 的话讲，它是 naive 的），与 Java 8 中的 LocalDateTime 类似。如果需要附加时区功能，可以通过 TimeZones.jl 包 实现，其汇编了来自 IANA 时区数据库 的数据。Date 和 DateTime 都基于 ISO 8601 标准，遵循公历（格里高利历）。 值得注意的是，ISO 8601 标准对公元前的日期需要特别处理。通常来说，公元前的最后一天是公元前 1 年的 12 月 31 日，接下来的一天是公元 1 年的 1 月 1 日，公元 0 年是不存在的。但是，在 ISO 8601 标准中，公元前 1 年被表示为 0 年，即 0001-01-01 的前一天是 0000-12-31，而 -0001（没错，年数为-1）的那一年则实际上是公元前 2 年，-0002 则表示公元前 3 年，以此类推。

构造函数

Date 和 DateTime 类型可以通过整数或 Period 类型，解析，或调整器来构造（稍后会详细介绍）：

1. julia> DateTime(2013)
2. 2013-01-01T00:00:00

4. julia> DateTime(2013,7)
5. 2013-07-01T00:00:00

7. julia> DateTime(2013,7,1)
8. 2013-07-01T00:00:00

10. julia> DateTime(2013,7,1,12)
11. 2013-07-01T12:00:00

13. julia> DateTime(2013,7,1,12,30)
14. 2013-07-01T12:30:00

16. julia> DateTime(2013,7,1,12,30,59)
17. 2013-07-01T12:30:59

19. julia> DateTime(2013,7,1,12,30,59,1)
20. 2013-07-01T12:30:59.001

22. julia> Date(2013)
23. 2013-01-01

25. julia> Date(2013,7)
26. 2013-07-01

28. julia> Date(2013,7,1)
29. 2013-07-01

31. julia> Date(Dates.Year(2013),Dates.Month(7),Dates.Day(1))
32. 2013-07-01

34. julia> Date(Dates.Month(7),Dates.Year(2013))
35. 2013-07-01

Date or DateTime parsing is accomplished by the use of format strings. Format strings work by the notion of defining delimited or fixed-width “slots” that contain a period to parse and passing the text to parse and format string to a Date or DateTime constructor, of the form Date("2015-01-01",dateformat"y-m-d") or DateTime("20150101",dateformat"yyyymmdd").

有分隔的插入点是通过指定解析器在两个时段之间的分隔符来进行标记的。例如，"y-m-d" 会告诉解析器，一个诸如 "2014-07-16" 的时间字符串，应该在第一个和第二个插入点之间查找 - 字符。y，m 和 d 字符则告诉解析器每一个插入点对应的时段名称。

As in the case of constructors above such as Date(2013), delimited DateFormats allow for missing parts of dates and times so long as the preceding parts are given. The other parts are given the usual default values. For example, Date("1981-03", dateformat"y-m-d") returns 1981-03-01, whilst Date("31/12", dateformat"d/m/y") gives 0001-12-31. (Note that the default year is 1 AD/CE.) Consequently, an empty string will always return 0001-01-01 for Dates, and 0001-01-01T00:00:00.000 for DateTimes.

Fixed-width slots are specified by repeating the period character the number of times corresponding to the width with no delimiter between characters. So dateformat"yyyymmdd" would correspond to a date string like "20140716". The parser distinguishes a fixed-width slot by the absence of a delimiter, noting the transition "yyyymm" from one period character to the next.

Support for text-form month parsing is also supported through the u and U characters, for abbreviated and full-length month names, respectively. By default, only English month names are supported, so u corresponds to “Jan”, “Feb”, “Mar”, etc. And U corresponds to “January”, “February”, “March”, etc. Similar to other name=>value mapping functions dayname and monthname, custom locales can be loaded by passing in the locale=>Dict{String,Int} mapping to the MONTHTOVALUEABBR and MONTHTOVALUE dicts for abbreviated and full-name month names, respectively.

The above examples used the dateformat"" string macro. This macro creates a DateFormat object once when the macro is expanded and uses the same DateFormat object even if a code snippet is run multiple times.

1. julia> for i = 1:10^5
2. Date("2015-01-01", dateformat"y-m-d")
3. end

Or you can create the DateFormat object explicitly:

1. julia> df = DateFormat("y-m-d");

3. julia> dt = Date("2015-01-01",df)
4. 2015-01-01

6. julia> dt2 = Date("2015-01-02",df)
7. 2015-01-02

Alternatively, use broadcasting:

1. julia> years = ["2015", "2016"];

3. julia> Date.(years, DateFormat("yyyy"))
4. 2-element Vector{Date}:
5. 2015-01-01
6. 2016-01-01

For convenience, you may pass the format string directly (e.g., Date("2015-01-01","y-m-d")), although this form incurs performance costs if you are parsing the same format repeatedly, as it internally creates a new DateFormat object each time.

As well as via the constructors, a Date or DateTime can be constructed from strings using the parse and tryparse functions, but with an optional third argument of type DateFormat specifying the format; for example, parse(Date, "06.23.2013", dateformat"m.d.y"), or tryparse(DateTime, "1999-12-31T23:59:59") which uses the default format. The notable difference between the functions is that with tryparse, an error is not thrown if the string is in an invalid format; instead nothing is returned. Note however that as with the constructors above, empty date and time parts assume default values and consequently an empty string ("") is valid for any DateFormat, giving for example a Date of 0001-01-01. Code relying on parse or tryparse for Date and DateTime parsing should therefore also check whether parsed strings are empty before using the result.

A full suite of parsing and formatting tests and examples is available in stdlib/Dates/test/io.jl.

Durations/Comparisons

Finding the length of time between two Date or DateTime is straightforward given their underlying representation as UTInstant{Day} and UTInstant{Millisecond}, respectively. The difference between Date is returned in the number of Day, and DateTime in the number of Millisecond. Similarly, comparing TimeType is a simple matter of comparing the underlying machine instants (which in turn compares the internal Int64 values).

1. julia> dt = Date(2012,2,29)
2. 2012-02-29

4. julia> dt2 = Date(2000,2,1)
5. 2000-02-01

7. julia> dump(dt)
8. Date
9. instant: Dates.UTInstant{Day}
10. periods: Day
11. value: Int64 734562

13. julia> dump(dt2)
14. Date
15. instant: Dates.UTInstant{Day}
16. periods: Day
17. value: Int64 730151

19. julia> dt > dt2
20. true

22. julia> dt != dt2
23. true

25. julia> dt + dt2
26. ERROR: MethodError: no method matching +(::Date, ::Date)
27. [...]

29. julia> dt * dt2
30. ERROR: MethodError: no method matching *(::Date, ::Date)
31. [...]

33. julia> dt / dt2
34. ERROR: MethodError: no method matching /(::Date, ::Date)

36. julia> dt - dt2
37. 4411 days

39. julia> dt2 - dt
40. -4411 days

42. julia> dt = DateTime(2012,2,29)
43. 2012-02-29T00:00:00

45. julia> dt2 = DateTime(2000,2,1)
46. 2000-02-01T00:00:00

48. julia> dt - dt2
49. 381110400000 milliseconds

Accessor Functions

Because the Date and DateTime types are stored as single Int64 values, date parts or fields can be retrieved through accessor functions. The lowercase accessors return the field as an integer:

1. julia> t = Date(2014, 1, 31)
2. 2014-01-31

4. julia> Dates.year(t)
5. 2014

7. julia> Dates.month(t)
8. 1

10. julia> Dates.week(t)
11. 5

13. julia> Dates.day(t)
14. 31

While propercase return the same value in the corresponding Period type:

1. julia> Dates.Year(t)
2. 2014 years

4. julia> Dates.Day(t)
5. 31 days

Compound methods are provided because it is more efficient to access multiple fields at the same time than individually:

1. julia> Dates.yearmonth(t)
2. (2014, 1)

4. julia> Dates.monthday(t)
5. (1, 31)

7. julia> Dates.yearmonthday(t)
8. (2014, 1, 31)

One may also access the underlying UTInstant or integer value:

1. julia> dump(t)
2. Date
3. instant: Dates.UTInstant{Day}
4. periods: Day
5. value: Int64 735264

7. julia> t.instant
8. Dates.UTInstant{Day}(Day(735264))

10. julia> Dates.value(t)
11. 735264

Query Functions

Query functions provide calendrical information about a TimeType. They include information about the day of the week:

1. julia> t = Date(2014, 1, 31)
2. 2014-01-31

4. julia> Dates.dayofweek(t)
5. 5

7. julia> Dates.dayname(t)
8. "Friday"

10. julia> Dates.dayofweekofmonth(t) # 5th Friday of January
11. 5

Month of the year:

1. julia> Dates.monthname(t)
2. "January"

4. julia> Dates.daysinmonth(t)
5. 31

As well as information about the TimeType‘s year and quarter:

1. julia> Dates.isleapyear(t)
2. false

4. julia> Dates.dayofyear(t)
5. 31

7. julia> Dates.quarterofyear(t)
8. 1

10. julia> Dates.dayofquarter(t)
11. 31

The dayname and monthname methods can also take an optional locale keyword that can be used to return the name of the day or month of the year for other languages/locales. There are also versions of these functions returning the abbreviated names, namely dayabbr and monthabbr. First the mapping is loaded into the LOCALES variable:

1. julia> french_months = ["janvier", "février", "mars", "avril", "mai", "juin",
2. "juillet", "août", "septembre", "octobre", "novembre", "décembre"];

4. julia> french_monts_abbrev = ["janv","févr","mars","avril","mai","juin",
5. "juil","août","sept","oct","nov","déc"];

7. julia> french_days = ["lundi","mardi","mercredi","jeudi","vendredi","samedi","dimanche"];

9. julia> Dates.LOCALES["french"] = Dates.DateLocale(french_months, french_monts_abbrev, french_days, [""]);

The above mentioned functions can then be used to perform the queries:

1. julia> Dates.dayname(t;locale="french")
2. "vendredi"

4. julia> Dates.monthname(t;locale="french")
5. "janvier"

7. julia> Dates.monthabbr(t;locale="french")
8. "janv"

Since the abbreviated versions of the days are not loaded, trying to use the function dayabbr will error.

1. julia> Dates.dayabbr(t;locale="french")
2. ERROR: BoundsError: attempt to access 1-element Vector{String} at index [5]
3. Stacktrace:
4. [...]

TimeType-Period Arithmetic

It’s good practice when using any language/date framework to be familiar with how date-period arithmetic is handled as there are some tricky issues to deal with (though much less so for day-precision types).

The Dates module approach tries to follow the simple principle of trying to change as little as possible when doing Period arithmetic. This approach is also often known as calendrical arithmetic or what you would probably guess if someone were to ask you the same calculation in a conversation. Why all the fuss about this? Let’s take a classic example: add 1 month to January 31st, 2014. What’s the answer? Javascript will say March 3 (assumes 31 days). PHP says March 2 (assumes 30 days). The fact is, there is no right answer. In the Dates module, it gives the result of February 28th. How does it figure that out? Consider the classic 7-7-7 gambling game in casinos.

Now just imagine that instead of 7-7-7, the slots are Year-Month-Day, or in our example, 2014-01-31. When you ask to add 1 month to this date, the month slot is incremented, so now we have 2014-02-31. Then the day number is checked if it is greater than the last valid day of the new month; if it is (as in the case above), the day number is adjusted down to the last valid day (28). What are the ramifications with this approach? Go ahead and add another month to our date, 2014-02-28 + Month(1) == 2014-03-28. What? Were you expecting the last day of March? Nope, sorry, remember the 7-7-7 slots. As few slots as possible are going to change, so we first increment the month slot by 1, 2014-03-28, and boom, we’re done because that’s a valid date. On the other hand, if we were to add 2 months to our original date, 2014-01-31, then we end up with 2014-03-31, as expected. The other ramification of this approach is a loss in associativity when a specific ordering is forced (i.e. adding things in different orders results in different outcomes). For example:

1. julia> (Date(2014,1,29)+Dates.Day(1)) + Dates.Month(1)
2. 2014-02-28

4. julia> (Date(2014,1,29)+Dates.Month(1)) + Dates.Day(1)
5. 2014-03-01

What’s going on there? In the first line, we’re adding 1 day to January 29th, which results in 2014-01-30; then we add 1 month, so we get 2014-02-30, which then adjusts down to 2014-02-28. In the second example, we add 1 month first, where we get 2014-02-29, which adjusts down to 2014-02-28, and then add 1 day, which results in 2014-03-01. One design principle that helps in this case is that, in the presence of multiple Periods, the operations will be ordered by the Periods’ types, not their value or positional order; this means Year will always be added first, then Month, then Week, etc. Hence the following does result in associativity and Just Works:

1. julia> Date(2014,1,29) + Dates.Day(1) + Dates.Month(1)
2. 2014-03-01

4. julia> Date(2014,1,29) + Dates.Month(1) + Dates.Day(1)
5. 2014-03-01

Tricky? Perhaps. What is an innocent Dates user to do? The bottom line is to be aware that explicitly forcing a certain associativity, when dealing with months, may lead to some unexpected results, but otherwise, everything should work as expected. Thankfully, that’s pretty much the extent of the odd cases in date-period arithmetic when dealing with time in UT (avoiding the “joys” of dealing with daylight savings, leap seconds, etc.).

As a bonus, all period arithmetic objects work directly with ranges:

1. julia> dr = Date(2014,1,29):Day(1):Date(2014,2,3)
2. Date("2014-01-29"):Day(1):Date("2014-02-03")

4. julia> collect(dr)
5. 6-element Vector{Date}:
6. 2014-01-29
7. 2014-01-30
8. 2014-01-31
9. 2014-02-01
10. 2014-02-02
11. 2014-02-03

13. julia> dr = Date(2014,1,29):Dates.Month(1):Date(2014,07,29)
14. Date("2014-01-29"):Month(1):Date("2014-07-29")

16. julia> collect(dr)
17. 7-element Vector{Date}:
18. 2014-01-29
19. 2014-02-28
20. 2014-03-29
21. 2014-04-29
22. 2014-05-29
23. 2014-06-29
24. 2014-07-29

Adjuster Functions

As convenient as date-period arithmetic is, often the kinds of calculations needed on dates take on a calendrical or temporal nature rather than a fixed number of periods. Holidays are a perfect example; most follow rules such as “Memorial Day = Last Monday of May”, or “Thanksgiving = 4th Thursday of November”. These kinds of temporal expressions deal with rules relative to the calendar, like first or last of the month, next Tuesday, or the first and third Wednesdays, etc.

The Dates module provides the adjuster API through several convenient methods that aid in simply and succinctly expressing temporal rules. The first group of adjuster methods deal with the first and last of weeks, months, quarters, and years. They each take a single TimeType as input and return or adjust to the first or last of the desired period relative to the input.

1. julia> Dates.firstdayofweek(Date(2014,7,16)) # Adjusts the input to the Monday of the input's week
2. 2014-07-14

4. julia> Dates.lastdayofmonth(Date(2014,7,16)) # Adjusts to the last day of the input's month
5. 2014-07-31

7. julia> Dates.lastdayofquarter(Date(2014,7,16)) # Adjusts to the last day of the input's quarter
8. 2014-09-30

The next two higher-order methods, tonext, and toprev, generalize working with temporal expressions by taking a DateFunction as first argument, along with a starting TimeType. A DateFunction is just a function, usually anonymous, that takes a single TimeType as input and returns a Bool, true indicating a satisfied adjustment criterion. For example:

1. julia> istuesday = x->Dates.dayofweek(x) == Dates.Tuesday; # Returns true if the day of the week of x is Tuesday

3. julia> Dates.tonext(istuesday, Date(2014,7,13)) # 2014-07-13 is a Sunday
4. 2014-07-15

6. julia> Dates.tonext(Date(2014,7,13), Dates.Tuesday) # Convenience method provided for day of the week adjustments
7. 2014-07-15

This is useful with the do-block syntax for more complex temporal expressions:

1. julia> Dates.tonext(Date(2014,7,13)) do x
2. # Return true on the 4th Thursday of November (Thanksgiving)
3. Dates.dayofweek(x) == Dates.Thursday &&
4. Dates.dayofweekofmonth(x) == 4 &&
5. Dates.month(x) == Dates.November
6. end
7. 2014-11-27

The Base.filter method can be used to obtain all valid dates/moments in a specified range:

1. # Pittsburgh street cleaning; Every 2nd Tuesday from April to November
2. # Date range from January 1st, 2014 to January 1st, 2015
3. julia> dr = Dates.Date(2014):Day(1):Dates.Date(2015);

5. julia> filter(dr) do x
6. Dates.dayofweek(x) == Dates.Tue &&
7. Dates.April <= Dates.month(x) <= Dates.Nov &&
8. Dates.dayofweekofmonth(x) == 2
9. end
10. 8-element Vector{Date}:
11. 2014-04-08
12. 2014-05-13
13. 2014-06-10
14. 2014-07-08
15. 2014-08-12
16. 2014-09-09
17. 2014-10-14
18. 2014-11-11

Additional examples and tests are available in stdlib/Dates/test/adjusters.jl.

Period Types

Periods are a human view of discrete, sometimes irregular durations of time. Consider 1 month; it could represent, in days, a value of 28, 29, 30, or 31 depending on the year and month context. Or a year could represent 365 or 366 days in the case of a leap year. Period types are simple Int64 wrappers and are constructed by wrapping any Int64 convertible type, i.e. Year(1) or Month(3.0). Arithmetic between Period of the same type behave like integers, and limited Period-Real arithmetic is available. You can extract the underlying integer with Dates.value.

1. julia> y1 = Dates.Year(1)
2. 1 year

4. julia> y2 = Dates.Year(2)
5. 2 years

7. julia> y3 = Dates.Year(10)
8. 10 years

10. julia> y1 + y2
11. 3 years

13. julia> div(y3,y2)
14. 5

16. julia> y3 - y2
17. 8 years

19. julia> y3 % y2
20. 0 years

22. julia> div(y3,3) # mirrors integer division
23. 3 years

25. julia> Dates.value(Dates.Millisecond(10))
26. 10

Rounding

Date and DateTime values can be rounded to a specified resolution (e.g., 1 month or 15 minutes) with floor, ceil, or round:

1. julia> floor(Date(1985, 8, 16), Dates.Month)
2. 1985-08-01

4. julia> ceil(DateTime(2013, 2, 13, 0, 31, 20), Dates.Minute(15))
5. 2013-02-13T00:45:00

7. julia> round(DateTime(2016, 8, 6, 20, 15), Dates.Day)
8. 2016-08-07T00:00:00

Unlike the numeric round method, which breaks ties toward the even number by default, the TimeTyperound method uses the RoundNearestTiesUp rounding mode. (It’s difficult to guess what breaking ties to nearest “even” TimeType would entail.) Further details on the available RoundingMode s can be found in the API reference.

Rounding should generally behave as expected, but there are a few cases in which the expected behaviour is not obvious.

Rounding Epoch

In many cases, the resolution specified for rounding (e.g., Dates.Second(30)) divides evenly into the next largest period (in this case, Dates.Minute(1)). But rounding behaviour in cases in which this is not true may lead to confusion. What is the expected result of rounding a DateTime to the nearest 10 hours?

1. julia> round(DateTime(2016, 7, 17, 11, 55), Dates.Hour(10))
2. 2016-07-17T12:00:00

That may seem confusing, given that the hour (12) is not divisible by 10. The reason that 2016-07-17T12:00:00 was chosen is that it is 17,676,660 hours after 0000-01-01T00:00:00, and 17,676,660 is divisible by 10.

As Julia Date and DateTime values are represented according to the ISO 8601 standard, 0000-01-01T00:00:00 was chosen as base (or “rounding epoch”) from which to begin the count of days (and milliseconds) used in rounding calculations. (Note that this differs slightly from Julia’s internal representation of Date s using Rata Die notation; but since the ISO 8601 standard is most visible to the end user, 0000-01-01T00:00:00 was chosen as the rounding epoch instead of the 0000-12-31T00:00:00 used internally to minimize confusion.)

The only exception to the use of 0000-01-01T00:00:00 as the rounding epoch is when rounding to weeks. Rounding to the nearest week will always return a Monday (the first day of the week as specified by ISO 8601). For this reason, we use 0000-01-03T00:00:00 (the first day of the first week of year 0000, as defined by ISO 8601) as the base when rounding to a number of weeks.

Here is a related case in which the expected behaviour is not necessarily obvious: What happens when we round to the nearest P(2), where P is a Period type? In some cases (specifically, when P <: Dates.TimePeriod) the answer is clear:

1. julia> round(DateTime(2016, 7, 17, 8, 55, 30), Dates.Hour(2))
2. 2016-07-17T08:00:00

4. julia> round(DateTime(2016, 7, 17, 8, 55, 30), Dates.Minute(2))
5. 2016-07-17T08:56:00

This seems obvious, because two of each of these periods still divides evenly into the next larger order period. But in the case of two months (which still divides evenly into one year), the answer may be surprising:

1. julia> round(DateTime(2016, 7, 17, 8, 55, 30), Dates.Month(2))
2. 2016-07-01T00:00:00

Why round to the first day in July, even though it is month 7 (an odd number)? The key is that months are 1-indexed (the first month is assigned 1), unlike hours, minutes, seconds, and milliseconds (the first of which are assigned 0).

This means that rounding a DateTime to an even multiple of seconds, minutes, hours, or years (because the ISO 8601 specification includes a year zero) will result in a DateTime with an even value in that field, while rounding a DateTime to an even multiple of months will result in the months field having an odd value. Because both months and years may contain an irregular number of days, whether rounding to an even number of days will result in an even value in the days field is uncertain.

See the API reference for additional information on methods exported from the Dates module.

API reference

Dates and Time Types

Dates.Period — Type

1. Period
2. Year
3. Quarter
4. Month
5. Week
6. Day
7. Hour
8. Minute
9. Second
10. Millisecond
11. Microsecond
12. Nanosecond

Period types represent discrete, human representations of time.

Dates.CompoundPeriod — Type

1. CompoundPeriod

A CompoundPeriod is useful for expressing time periods that are not a fixed multiple of smaller periods. For example, “a year and a day” is not a fixed number of days, but can be expressed using a CompoundPeriod. In fact, a CompoundPeriod is automatically generated by addition of different period types, e.g. Year(1) + Day(1) produces a CompoundPeriod result.

Dates.Instant — Type

1. Instant

Instant types represent integer-based, machine representations of time as continuous timelines starting from an epoch.

Dates.UTInstant — Type

1. UTInstant{T}

The UTInstant represents a machine timeline based on UT time (1 day = one revolution of the earth). The T is a Period parameter that indicates the resolution or precision of the instant.

Dates.TimeType — Type

1. TimeType

TimeType types wrap Instant machine instances to provide human representations of the machine instant. Time, DateTime and Date are subtypes of TimeType.

Dates.DateTime — Type

1. DateTime

DateTime wraps a UTInstant{Millisecond} and interprets it according to the proleptic Gregorian calendar.

Dates.Date — Type

1. Date

Date wraps a UTInstant{Day} and interprets it according to the proleptic Gregorian calendar.

Dates.Time — Type

1. Time

Time wraps a Nanosecond and represents a specific moment in a 24-hour day.

Dates.TimeZone — Type

1. TimeZone

Geographic zone generally based on longitude determining what the time is at a certain location. Some time zones observe daylight savings (eg EST -> EDT). For implementations and more support, see the TimeZones.jl package

Dates.UTC — Type

1. UTC

UTC, or Coordinated Universal Time, is the TimeZone from which all others are measured. It is associated with the time at 0° longitude. It is not adjusted for daylight savings.

Dates Functions

Dates.DateTime — Method

1. DateTime(y, [m, d, h, mi, s, ms]) -> DateTime

Construct a DateTime type by parts. Arguments must be convertible to Int64.

Dates.DateTime — Method

1. DateTime(periods::Period...) -> DateTime

Construct a DateTime type by Period type parts. Arguments may be in any order. DateTime parts not provided will default to the value of Dates.default(period).

Dates.DateTime — Method

1. DateTime(f::Function, y[, m, d, h, mi, s]; step=Day(1), limit=10000) -> DateTime

Create a DateTime through the adjuster API. The starting point will be constructed from the provided y, m, d... arguments, and will be adjusted until f::Function returns true. The step size in adjusting can be provided manually through the step keyword. limit provides a limit to the max number of iterations the adjustment API will pursue before throwing an error (in the case that f::Function is never satisfied).

Examples

1. julia> DateTime(dt -> Dates.second(dt) == 40, 2010, 10, 20, 10; step = Dates.Second(1))
2. 2010-10-20T10:00:40

4. julia> DateTime(dt -> Dates.hour(dt) == 20, 2010, 10, 20, 10; step = Dates.Hour(1), limit = 5)
5. ERROR: ArgumentError: Adjustment limit reached: 5 iterations
6. Stacktrace:
7. [...]

Dates.DateTime — Method

1. DateTime(dt::Date) -> DateTime

Convert a Date to a DateTime. The hour, minute, second, and millisecond parts of the new DateTime are assumed to be zero.

Dates.DateTime — Method

1. DateTime(dt::AbstractString, format::AbstractString; locale="english") -> DateTime

Construct a DateTime by parsing the dt date time string following the pattern given in the format string (see DateFormat for syntax).

Note

This method creates a DateFormat object each time it is called. It is recommended that you create a DateFormat object instead and use that as the second argument to avoid performance loss when using the same format repeatedly.

Example

1. julia> DateTime("2020-01-01", "yyyy-mm-dd")
2. 2020-01-01T00:00:00

4. julia> a = ("2020-01-01", "2020-01-02");

6. julia> [DateTime(d, dateformat"yyyy-mm-dd") for d ∈ a] # preferred
7. 2-element Vector{DateTime}:
8. 2020-01-01T00:00:00
9. 2020-01-02T00:00:00

Dates.format — Method

1. format(dt::TimeType, format::AbstractString; locale="english") -> AbstractString

Construct a string by using a TimeType object and applying the provided format. The following character codes can be used to construct the format string:

The number of sequential code characters indicate the width of the code. A format of yyyy-mm specifies that the code y should have a width of four while m a width of two. Codes that yield numeric digits have an associated mode: fixed-width or minimum-width. The fixed-width mode left-pads the value with zeros when it is shorter than the specified width and truncates the value when longer. Minimum-width mode works the same as fixed-width except that it does not truncate values longer than the width.

When creating a format you can use any non-code characters as a separator. For example to generate the string “1996-01-15T00:00:00” you could use format: “yyyy-mm-ddTHH:MM:SS”. Note that if you need to use a code character as a literal you can use the escape character backslash. The string “1996y01m” can be produced with the format “yyyy\ymm\m”.

Dates.DateFormat — Type

1. DateFormat(format::AbstractString, locale="english") -> DateFormat

Construct a date formatting object that can be used for parsing date strings or formatting a date object as a string. The following character codes can be used to construct the format string:

Characters not listed above are normally treated as delimiters between date and time slots. For example a dt string of “1996-01-15T00:00:00.0” would have a format string like “y-m-dTH:M:S.s”. If you need to use a code character as a delimiter you can escape it using backslash. The date “1995y01m” would have the format “y\ym\m”.

Note that 12:00AM corresponds 00:00 (midnight), and 12:00PM corresponds to 12:00 (noon). When parsing a time with a p specifier, any hour (either H or I) is interpreted as as a 12-hour clock, so the I code is mainly useful for output.

Creating a DateFormat object is expensive. Whenever possible, create it once and use it many times or try the dateformat”” string macro. Using this macro creates the DateFormat object once at macro expansion time and reuses it later. There are also several pre-defined formatters, listed later.

See DateTime and format for how to use a DateFormat object to parse and write Date strings respectively.

Dates.@dateformat_str — Macro

1. dateformat"Y-m-d H:M:S"

Create a DateFormat object. Similar to DateFormat("Y-m-d H:M:S") but creates the DateFormat object once during macro expansion.

See DateFormat for details about format specifiers.

Dates.DateTime — Method

1. DateTime(dt::AbstractString, df::DateFormat=ISODateTimeFormat) -> DateTime

Construct a DateTime by parsing the dt date time string following the pattern given in the DateFormat object, or dateformat”yyyy-mm-ddTHH:MM:SS.s” if omitted.

Similar to DateTime(::AbstractString, ::AbstractString) but more efficient when repeatedly parsing similarly formatted date time strings with a pre-created DateFormat object.

Dates.Date — Method

1. Date(y, [m, d]) -> Date

Construct a Date type by parts. Arguments must be convertible to Int64.

Dates.Date — Method

1. Date(period::Period...) -> Date

Construct a Date type by Period type parts. Arguments may be in any order. Date parts not provided will default to the value of Dates.default(period).

Dates.Date — Method

1. Date(f::Function, y[, m, d]; step=Day(1), limit=10000) -> Date

Create a Date through the adjuster API. The starting point will be constructed from the provided y, m, d arguments, and will be adjusted until f::Function returns true. The step size in adjusting can be provided manually through the step keyword. limit provides a limit to the max number of iterations the adjustment API will pursue before throwing an error (given that f::Function is never satisfied).

Examples

1. julia> Date(date -> Dates.week(date) == 20, 2010, 01, 01)
2. 2010-05-17

4. julia> Date(date -> Dates.year(date) == 2010, 2000, 01, 01)
5. 2010-01-01

7. julia> Date(date -> Dates.month(date) == 10, 2000, 01, 01; limit = 5)
8. ERROR: ArgumentError: Adjustment limit reached: 5 iterations
9. Stacktrace:
10. [...]

Dates.Date — Method

1. Date(dt::DateTime) -> Date

Convert a DateTime to a Date. The hour, minute, second, and millisecond parts of the DateTime are truncated, so only the year, month and day parts are used in construction.

Dates.Date — Method

1. Date(d::AbstractString, format::AbstractString; locale="english") -> Date

Construct a Date by parsing the d date string following the pattern given in the format string (see DateFormat for syntax).

Note

This method creates a DateFormat object each time it is called. It is recommended that you create a DateFormat object instead and use that as the second argument to avoid performance loss when using the same format repeatedly.

Example

1. julia> Date("2020-01-01", "yyyy-mm-dd")
2. 2020-01-01

4. julia> a = ("2020-01-01", "2020-01-02");

6. julia> [Date(d, dateformat"yyyy-mm-dd") for d ∈ a] # preferred
7. 2-element Vector{Date}:
8. 2020-01-01
9. 2020-01-02

Dates.Date — Method

1. Date(d::AbstractString, df::DateFormat=ISODateFormat) -> Date

Construct a Date by parsing the d date string following the pattern given in the DateFormat object, or dateformat”yyyy-mm-dd” if omitted.

Similar to Date(::AbstractString, ::AbstractString) but more efficient when repeatedly parsing similarly formatted date strings with a pre-created DateFormat object.

Dates.Time — Method

1. Time(h, [mi, s, ms, us, ns]) -> Time

Construct a Time type by parts. Arguments must be convertible to Int64.

Dates.Time — Method

1. Time(period::TimePeriod...) -> Time

Construct a Time type by Period type parts. Arguments may be in any order. Time parts not provided will default to the value of Dates.default(period).

Dates.Time — Method

1. Time(f::Function, h, mi=0; step::Period=Second(1), limit::Int=10000)
2. Time(f::Function, h, mi, s; step::Period=Millisecond(1), limit::Int=10000)
3. Time(f::Function, h, mi, s, ms; step::Period=Microsecond(1), limit::Int=10000)
4. Time(f::Function, h, mi, s, ms, us; step::Period=Nanosecond(1), limit::Int=10000)

Create a Time through the adjuster API. The starting point will be constructed from the provided h, mi, s, ms, us arguments, and will be adjusted until f::Function returns true. The step size in adjusting can be provided manually through the step keyword. limit provides a limit to the max number of iterations the adjustment API will pursue before throwing an error (in the case that f::Function is never satisfied). Note that the default step will adjust to allow for greater precision for the given arguments; i.e. if hour, minute, and second arguments are provided, the default step will be Millisecond(1) instead of Second(1).

Examples

1. julia> Dates.Time(t -> Dates.minute(t) == 30, 20)
2. 20:30:00

4. julia> Dates.Time(t -> Dates.minute(t) == 0, 20)
5. 20:00:00

7. julia> Dates.Time(t -> Dates.hour(t) == 10, 3; limit = 5)
8. ERROR: ArgumentError: Adjustment limit reached: 5 iterations
9. Stacktrace:
10. [...]

Dates.Time — Method

1. Time(dt::DateTime) -> Time

Convert a DateTime to a Time. The hour, minute, second, and millisecond parts of the DateTime are used to create the new Time. Microsecond and nanoseconds are zero by default.

Dates.Time — Method

1. Time(t::AbstractString, format::AbstractString; locale="english") -> Time

Construct a Time by parsing the t time string following the pattern given in the format string (see DateFormat for syntax).

Note

This method creates a DateFormat object each time it is called. It is recommended that you create a DateFormat object instead and use that as the second argument to avoid performance loss when using the same format repeatedly.

Example

1. julia> Time("12:34pm", "HH:MMp")
2. 12:34:00

4. julia> a = ("12:34pm", "2:34am");

6. julia> [Time(d, dateformat"HH:MMp") for d ∈ a] # preferred
7. 2-element Vector{Time}:
8. 12:34:00
9. 02:34:00

Dates.Time — Method

1. Time(t::AbstractString, df::DateFormat=ISOTimeFormat) -> Time

Construct a Time by parsing the t date time string following the pattern given in the DateFormat object, or dateformat”HH:MM:SS.s” if omitted.

Similar to Time(::AbstractString, ::AbstractString) but more efficient when repeatedly parsing similarly formatted time strings with a pre-created DateFormat object.

Dates.now — Method

1. now() -> DateTime

Return a DateTime corresponding to the user’s system time including the system timezone locale.

Dates.now — Method

1. now(::Type{UTC}) -> DateTime

Return a DateTime corresponding to the user’s system time as UTC/GMT.

Base.eps — Method

1. eps(::Type{DateTime}) -> Millisecond
2. eps(::Type{Date}) -> Day
3. eps(::Type{Time}) -> Nanosecond
4. eps(::TimeType) -> Period

Return the smallest unit value supported by the TimeType.

Examples

1. julia> eps(DateTime)
2. 1 millisecond

4. julia> eps(Date)
5. 1 day

7. julia> eps(Time)
8. 1 nanosecond

Accessor Functions

Dates.year — Function

1. year(dt::TimeType) -> Int64

The year of a Date or DateTime as an Int64.

Dates.month — Function

1. month(dt::TimeType) -> Int64

The month of a Date or DateTime as an Int64.

Dates.week — Function

1. week(dt::TimeType) -> Int64

Return the ISO week date of a Date or DateTime as an Int64. Note that the first week of a year is the week that contains the first Thursday of the year, which can result in dates prior to January 4th being in the last week of the previous year. For example, week(Date(2005, 1, 1)) is the 53rd week of 2004.

Examples

1. julia> Dates.week(Date(1989, 6, 22))
2. 25

4. julia> Dates.week(Date(2005, 1, 1))
5. 53

7. julia> Dates.week(Date(2004, 12, 31))
8. 53

Dates.day — Function

1. day(dt::TimeType) -> Int64

The day of month of a Date or DateTime as an Int64.

Dates.hour — Function

1. hour(dt::DateTime) -> Int64

The hour of day of a DateTime as an Int64.

1. hour(t::Time) -> Int64

The hour of a Time as an Int64.

Dates.minute — Function

1. minute(dt::DateTime) -> Int64

The minute of a DateTime as an Int64.

1. minute(t::Time) -> Int64

The minute of a Time as an Int64.

Dates.second — Function

1. second(dt::DateTime) -> Int64

The second of a DateTime as an Int64.

1. second(t::Time) -> Int64

The second of a Time as an Int64.

Dates.millisecond — Function

1. millisecond(dt::DateTime) -> Int64

The millisecond of a DateTime as an Int64.

1. millisecond(t::Time) -> Int64

The millisecond of a Time as an Int64.

Dates.microsecond — Function

1. microsecond(t::Time) -> Int64

The microsecond of a Time as an Int64.

Dates.nanosecond — Function

1. nanosecond(t::Time) -> Int64

The nanosecond of a Time as an Int64.

Dates.Year — Method

1. Year(v)

Construct a Year object with the given v value. Input must be losslessly convertible to an Int64.

Dates.Month — Method

1. Month(v)

Construct a Month object with the given v value. Input must be losslessly convertible to an Int64.

Dates.Week — Method

1. Week(v)

Construct a Week object with the given v value. Input must be losslessly convertible to an

（本文超出站点单文档体积上限，已截断）