复数和有理数

Julia 语言包含了预定义的复数和有理数类型，并且支持它们的各种标准数学运算和初等函数。由于也定义了复数与分数的类型转换与类型提升，因此对预定义数值类型（无论是原始的还是复合的）的任意组合进行的操作都会表现得如预期的一样。

复数

在Julia中,全局常量 im 被绑定到复数 i，表示 -1 的主平方根（不应使用数学家习惯的 i 或工程师习惯的 j 来表示此全局常量，因为它们是非常常用的索引变量名）。由于 Julia 允许数值字面量作为系数与标识符并置，这种绑定就足够为复数提供很方便的语法，类似于传统的数学记法：

1. julia> 1+2im
2. 1 + 2im

你可以对复数进行各种标准算术操作：

1. julia> (1 + 2im)*(2 - 3im)
2. 8 + 1im

4. julia> (1 + 2im)/(1 - 2im)
5. -0.6 + 0.8im

7. julia> (1 + 2im) + (1 - 2im)
8. 2 + 0im

10. julia> (-3 + 2im) - (5 - 1im)
11. -8 + 3im

13. julia> (-1 + 2im)^2
14. -3 - 4im

16. julia> (-1 + 2im)^2.5
17. 2.729624464784009 - 6.9606644595719im

19. julia> (-1 + 2im)^(1 + 1im)
20. -0.27910381075826657 + 0.08708053414102428im

22. julia> 3(2 - 5im)
23. 6 - 15im

25. julia> 3(2 - 5im)^2
26. -63 - 60im

28. julia> 3(2 - 5im)^-1.0
29. 0.20689655172413796 + 0.5172413793103449im

类型提升机制也确保你可以使用不同类型的操作数的组合：

1. julia> 2(1 - 1im)
2. 2 - 2im

4. julia> (2 + 3im) - 1
5. 1 + 3im

7. julia> (1 + 2im) + 0.5
8. 1.5 + 2.0im

10. julia> (2 + 3im) - 0.5im
11. 2.0 + 2.5im

13. julia> 0.75(1 + 2im)
14. 0.75 + 1.5im

16. julia> (2 + 3im) / 2
17. 1.0 + 1.5im

19. julia> (1 - 3im) / (2 + 2im)
20. -0.5 - 1.0im

22. julia> 2im^2
23. -2 + 0im

25. julia> 1 + 3/4im
26. 1.0 - 0.75im

注意 3/4im == 3/(4*im) == -(3/4*im)，因为系数比除法的优先级更高。

Julia 提供了一些操作复数的标准函数：

1. julia> z = 1 + 2im
2. 1 + 2im

4. julia> real(1 + 2im) # z 的实部
5. 1

7. julia> imag(1 + 2im) # z 的虚部
8. 2

10. julia> conj(1 + 2im) # z 的复共轭
11. 1 - 2im

13. julia> abs(1 + 2im) # z 的绝对值
14. 2.23606797749979

16. julia> abs2(1 + 2im) # 取平方后的绝对值
17. 5

19. julia> angle(1 + 2im) # 以弧度为单位的相位角
20. 1.1071487177940904

按照惯例，复数的绝对值（abs）是从零点到它的距离。abs2 给出绝对值的平方，作用于复数上时非常有用，因为它避免了取平方根。angle 返回以弧度为单位的相位角（也被称为辐角函数）。所有其它的初等函数在复数上也都有完整的定义：

1. julia> sqrt(1im)
2. 0.7071067811865476 + 0.7071067811865475im

4. julia> sqrt(1 + 2im)
5. 1.272019649514069 + 0.7861513777574233im

7. julia> cos(1 + 2im)
8. 2.0327230070196656 - 3.0518977991518im

10. julia> exp(1 + 2im)
11. -1.1312043837568135 + 2.4717266720048188im

13. julia> sinh(1 + 2im)
14. -0.4890562590412937 + 1.4031192506220405im

注意数学函数通常应用于实数就返回实数值，应用于复数就返回复数值。例如，当 sqrt 应用于 -1 与 -1 + 0im 会有不同的表现，虽然 -1 == -1 + 0im：

1. julia> sqrt(-1)
2. ERROR: DomainError with -1.0:
3. sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
4. Stacktrace:
5. [...]

7. julia> sqrt(-1 + 0im)
8. 0.0 + 1.0im

从变量构建复数时，文本型数值系数记法不再适用。相反地，乘法必须显式地写出：

1. julia> a = 1; b = 2; a + b*im
2. 1 + 2im

然而，我们并不推荐这样做，而应改为使用更高效的 complex 函数直接通过实部与虚部构建一个复数值：

1. julia> a = 1; b = 2; complex(a, b)
2. 1 + 2im

这种构建避免了乘法和加法操作。

Inf 和 NaN 可能出现在复数的实部和虚部，正如特殊的浮点值章节所描述的：

1. julia> 1 + Inf*im
2. 1.0 + Inf*im

4. julia> 1 + NaN*im
5. 1.0 + NaN*im

有理数

Julia 有一个用于表示整数精确比值的分数类型。分数通过 // 运算符构建：

1. julia> 2//3
2. 2//3

如果一个分数的分子和分母含有公因子，它们会被约分到最简形式且分母非负：

1. julia> 6//9
2. 2//3

4. julia> -4//8
5. -1//2

7. julia> 5//-15
8. -1//3

10. julia> -4//-12
11. 1//3

整数比值的这种标准化形式是唯一的，所以分数值的相等性可由校验分子与分母都相等来测试。分数值的标准化分子和分母可以使用 numerator 和 denominator 函数得到：

1. julia> numerator(2//3)
2. 2

4. julia> denominator(2//3)
5. 3

分子和分母的直接比较通常是不必要的，因为标准算术和比较操作对分数值也有定义：

1. julia> 2//3 == 6//9
2. true

4. julia> 2//3 == 9//27
5. false

7. julia> 3//7 < 1//2
8. true

10. julia> 3//4 > 2//3
11. true

13. julia> 2//4 + 1//6
14. 2//3

16. julia> 5//12 - 1//4
17. 1//6

19. julia> 5//8 * 3//12
20. 5//32

22. julia> 6//5 / 10//7
23. 21//25

分数可以很容易地转换成浮点数：

1. julia> float(3//4)
2. 0.75

对任意整数值 a 和 b（除了 a == 0 且 b == 0 时），从分数到浮点数的转换遵从以下的一致性：

1. julia> a = 1; b = 2;

3. julia> isequal(float(a//b), a/b)
4. true

Julia接受构建无穷分数值：

1. julia> 5//0
2. 1//0

4. julia> -3//0
5. -1//0

7. julia> typeof(ans)
8. Rational{Int64}

但不接受试图构建一个 NaN 分数值：

1. julia> 0//0
2. ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
3. Stacktrace:
4. [...]

像往常一样，类型提升系统使得分数可以轻松地同其它数值类型进行交互：

1. julia> 3//5 + 1
2. 8//5

4. julia> 3//5 - 0.5
5. 0.09999999999999998

7. julia> 2//7 * (1 + 2im)
8. 2//7 + 4//7*im

10. julia> 2//7 * (1.5 + 2im)
11. 0.42857142857142855 + 0.5714285714285714im

13. julia> 3//2 / (1 + 2im)
14. 3//10 - 3//5*im

16. julia> 1//2 + 2im
17. 1//2 + 2//1*im

19. julia> 1 + 2//3im
20. 1//1 - 2//3*im

22. julia> 0.5 == 1//2
23. true

25. julia> 0.33 == 1//3
26. false

28. julia> 0.33 < 1//3
29. true

31. julia> 1//3 - 0.33
32. 0.0033333333333332993